User:Pamputt

SELECT DISTINCT ?item ?itemLabel ?itemDescription ?iso
{  
	?item wdt:P220 ?iso . # looking for language
	MINUS { ?item wdt:P1394 [] } . # with missing Glottolog ID
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
    FILTER(NOT EXISTS {
    ?item rdf:type wdno:P1394 . # dont le code Glottolog n'a pas la valeur « aucune valeur »
    ?item schema:description ?itemDescription .
    FILTER(LANG(?itemDescription) = "fr") # with missing French description
    })
}
ORDER BY ?itemLabel

select ?item ?itemLabel ?number
with { # select all the numbers of sitelinks
  select ?number (count(*) as ?total) { # we don't use ?total but without it the query times out, so we'll just ignore it
    [] wikibase:sitelinks ?number .
  } group by ?number
} as %numbers
where {
  # include the numbers of sitelinks from above and filter out any numbers lower than 40
  # the higher the number here, the fewer items there are to check and the faster this query will run
  include %numbers .
  filter (?number > 40) .

  # find items where the number of sitelinks is one of the remaining numbers, i.e. greater than 40
  ?item wikibase:sitelinks ?number .
  
  # filter out various uninteresting things
  minus { ?item wdt:P31/wdt:P279* wd:Q11266439 } # No templates
  minus { ?item wdt:P31/wdt:P279* wd:Q4167836 } # No categories
  minus { ?item wdt:P31/wdt:P279* wd:Q17442446 } # No other Wikipedia/Help pages
  minus { ?item wdt:P31 wd:Q14204246 } # No project pages
  minus { ?item wdt:P31 wd:Q15184295 } # No modules

  # filter out items which have an frwiki sitelink
  minus { ?article schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> }

  service wikibase:label { bd:serviceParam wikibase:language "fr" }
} order by desc(?number)

SELECT DISTINCT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P106 wd:Q36834; # compositeur
    wdt:P21 wd:Q6581072; # de sexe féminin
    wdt:P135 wd:Q9730. # apparenté au mouvement de la musique classique
  MINUS { ?item wdt:P8523 _:b18. } # sans identifiant Presence compositrices
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
ORDER BY (?itemLabel)

SELECT DISTINCT ?item ?itemLabel ?itemDescription ?gender
{  
	?item wdt:P31 wd:Q5 . # looking for human
	?item wdt:P166 ?award .
    ?award wdt:P279* wd:Q7191 . # awarded by Nobel prize
    ?item  wdt:P21 ?gender .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
}
ORDER BY ?gender